AutoHotKey

Last-modified: 2016-12-06 (火) 04:56:54

この記事は書き直しが必要だと考えられます。このページへのリンクをする前に
http://jbbs.shitaraba.net/bbs/read.cgi/game/59977/1480929569/ で合意形成してください。

書き直し前

AutoHotKeyを使うと標準のキー設定を超えた細かいキー操作が可能になる

設定サンプル

設定されたショートカット一覧

無変換+F1: このヘルプを表示
無変換+F11: AutoHotKeyスクリプトを一時停止
無変換+F12: AutoHotKeyスクリプトをリロード
Ctrl+E: Enter
Ctrl+Q: ESC
Ctrl+T: (セーブダイアログで)今日の日付＋時刻を入力
Ctrl+右クリック: カーソル位置の対象を壊し続ける(もう一度右クリックで解除)
Ctr+F: アイテムを拾い続ける(もう一度Fで解除)
Ctrl+ホイールアップ: クイックスロット9を選択
Ctrl+ホイールダウン: クイックスロット10を選択
Ctrl+A: 対象を回転させる(R)
無変換+1: 10回左クリック(アイテムをまとめて作るときに使用)
無変換+2: 20回左クリック(アイテムをまとめて作るときに使用)
無変換+3: 5回左クリック(アイテムをまとめて作るときに使用)
無変換+K: Wikiを開く
無変換+G: Google検索
無変換+A: マップ表示
無変換+S: 一時停止
無変換+D: ユーザードキュメントを表示(要設定)
無変換+Q: ESC

サンプルコード

#IfWinActive,ahk_exe Factorio.exe
vk1Dsc07B & F11::
	Suspend,Permit
	Suspend,Toggle
	return
vk1Dsc07B & F12::
	Suspend,Permit
	Suspend,Off
	Reload
	return
^t:: factorio_send_datetime()
vk1Dsc07B & F1:: factorio_show_help()
^f::
	Send,{f up}
	Send,{f down}
	factorio_set_title("[Auto Pickup]")
	return
f::
	Send,{f down}
	factorio_set_title("")
	return
f up:: Send,{f up}
^RButton::
	Send,{RButton up}
	Send,{RButton down}
	factorio_set_title("[Auto Dig]")
	return
RButton::
	send,{RButton down}
	factorio_set_title("")
	return
RButton up:: send,{RButton up}
^E:: Send,{Enter}
^Q:: Send,{ESC}
^A:: Send,r
vk1Dsc07B & K:: run,http://wikiwiki.jp/factorio/
vk1Dsc07B & 1:: Send,{LButton 10}
vk1Dsc07B & 2:: Send,{LButton 20}
vk1Dsc07B & 3:: Send,{LButton 5}
vk1Dsc07B & A:: Send,m
vk1Dsc07B & S:: Send,+{Space}
vk1Dsc07B & D:: run,d:\factorio_user_document.txt
vk1Dsc07B & Q:: Send,{ESC}
^WheelUp:: Send,+4
^WheelDown:: Send,+5
WheelUp:: Send,{WheelUp 5}
WheelDown:: Send,{WheelDown 5}
;; common
factorio_set_title(stat)
{
	global factorio_title
	if factorio_title=
		WinGetTitle,factorio_title
	WinSetTitle,%factorio_title% %stat%
}
factorio_send_datetime()
{
	FormatTime,fn,,yyyyMMdd-HHmm
	send,{home}+{end}%fn%
}
factorio_show_help()
{
	mes=
(
無変換+F1: このヘルプを表示
無変換+F11: AutoHotKeyスクリプトを一時停止
無変換+F12: AutoHotKeyスクリプトをリロード
Ctrl+E: Enter
Ctrl+Q: ESC
Ctrl+T: (セーブダイアログで)今日の日付＋時刻を入力
Ctrl+右クリック: カーソル位置の対象を壊し続ける(もう一度右クリックで解除)
Ctr+F: アイテムを拾い続ける(もう一度Fで解除)
Ctrl+ホイールアップ: クイックスロット9を選択
Ctrl+ホイールダウン: クイックスロット10を選択
Ctrl+A: 対象を回転させる(R)
無変換+1: 10回左クリック(アイテムをまとめて作るときに使用)
無変換+2: 20回左クリック(アイテムをまとめて作るときに使用)
無変換+3: 5回左クリック(アイテムをまとめて作るときに使用)
無変換+K: Wikiを開く
無変換+G: Google検索
無変換+A: マップ表示
無変換+S: 一時停止
無変換+D: ユーザードキュメントを表示(要設定)
無変換+Q: ESC
)
	msgbox,32,Factorio.ahkヘルプ,%mes%
}

Factorio Launcher

無変換＋Lで起動する2ストロークランチャ
ローカルフォルダに関連するものは各自パスを書き換えて使用する

#IfWinActive,ahk_exe factorio.exe
vk1Dsc07B & L:: factorio_launcher()
#IfWinActive,Factorio Launcher
factorio_launcher()
{
	Msgbox,,Factorio Launcher,
(
O: オフィシャルサイト
S: Steam
W: Wiki(Jp)
K: Wiki(En)
ローカルフォルダ --------------------
B: インストールフォルダ
V: セーブデータフォルダ
D: ユーザードキュメント
T: スクリーンショットフォルダ
検索 --------------------
2: 2chスレッド検索
G: Google検索
M: Google MOD検索
動画検索 --------------------
Y: YouTube
N: ニコニコ動画
)
}
O::
	Send,{ESC}
	run,https://www.factorio.com/
	return
S::
	Send,{ESC}
	run,http://store.steampowered.com/app/427520/
	return
W::
	Send,{ESC}
	run,http://wikiwiki.jp/factorio/
	return
K::
	Send,{ESC}
	run,https://wiki.factorio.com/Main_Page/ja
	return
2::
	Send,{ESC}
	run,https://ff2ch.syoboi.jp/?q=Factorio
	return
G::
	Send,{ESC}
	InputBox,wd,Factorio Search
	if ErrorLevel
		return
	run,https://www.google.co.jp/search?q=Factorio+%wd%&gws_rd=ssl
	return
M::
	Send,{ESC}
	InputBox,wd,Factorio Mod Search
	if ErrorLevel
		return
	run,https://www.google.co.jp/search?q=Factorio+Mod+%wd%&gws_rd=ssl
	return
B::
	Send,{ESC}
	run,c:\bin\factorio
V::
	Send,{ESC}
	run,%appdata%\Factorio
	return
D::
	Send,{ESC}
	run,d:\factoriomemo.txt
	return
T::
	Send,{ESC}
	run,c:\screenshot
	return
Y::
	Send,{ESC}
	InputBox,wd,Factorio YouTube Search
	if ErrorLevel
		return
	run,https://www.youtube.com/results?search_query=Factorio+%wd%
	return
N::
	Send,{ESC}
	InputBox,wd,Factorio Nico Search
	if ErrorLevel
		return
	run,http://www.nicovideo.jp/search/Factorio`%20%wd%
	return